連載 [第2回] :
  PerlでWeb APIを使いたおす

XML-RPCを利用したWeb API

2006年10月2日(月)
水野 貴明

XML-RPCサーバーの実装


   続いてはXML-RPCサーバーを実装してみることにしましょう。RPC-XMLモジュールにはサーバーを立てるためのツールも用意されているので、それを利用します。

   今回作成したのは2つの整数を受け取ってそれを足し算して返す「example.sum」というメソッドです。まずはサンプルを見てみることにしましょう(リスト9)。


リスト9:XML-RPCサーバーのサンプル
#!/usr/bin/perl
use RPC::XML::Server;
my $host = "www.example.com";
my $port = "9001";
my $server = RPC::XML::Server->new(
      host => $host,
      port => $port,
);

my $example_sum = RPC::XML::Procedure->new(
    { name      => 'example.sum',
      code      => \&example_sum,
      signature => ['i4 i4 i4'] }
);
$server->add_method($example_sum);
$server->server_loop;

sub example_sum {
      my ($num1, $num2 ) = @_;
      return $num1 + $num2;
}

   まずはサーバーのホスト名とポート番号を指定してRPC::XML::Serverクラスのインスタンスを作ります。続いてadd_methodメソッドで提供するメソッドを追加していきます。メソッドを追加するにはまずRPC::XML::Procedureクラスのインスタンスを作ります。作成の際にはメソッドの名前、呼び出されるサブルーチン、パラメータを指定します。パラメータの指定は、戻り値と渡すパラメータをスペース区切りの文字列として渡します。

   最後にserver_loopを呼び出せば、サーバーはクライアントからのアクセスを待ち受ける状態となります。

   クライアントからの要求があったときに実際に呼び出されるサブルーチンexample_sumでは、引数に実際に渡されたパラメータが入ります。XMLとの相互変換等は全てXML-RPCがやってくれるため、通常のサブルーチンとほぼ同じように書けるのが特長です。

   なお、このAPIにアクセスするクライアントはリスト10のようになるでしょう。

リスト10:example.sumにアクセスするクライアント
#!/usr/bin/perl
use strict;
use warnings;
use RPC::XML::Client;

my $client = RPC::XML::Client->new('http://www.example.com:9001/');
my $req = RPC::XML::request->new(
  'example.sum',
  RPC::XML::i4->new('10'),
  RPC::XML::i4->new('23'),
);

my $res = $client->send_request($req);
if( $res->is_fault ){
    print "ERROR: ".$res->value->{faultString}."\n";
}else{
    print "SUM: ".$res->value."\n";
}

   リスト9に示したサンプルは、独自のWebサーバーを立ち上げるものです。しかしすでにサーバーが立ち上がっていて、あるURLへのアクセスのみをXML-RPCのリクエストとして処理したい場合には、受け取ったデータをRPC::XML::Parserだけを使って処理することも可能です(リスト11)。

リスト11:データの処理をRPC::XML::Parserで行う
my $reqobj = RPC::XML::Parser->new->parse($request);
my $name = $reqobj->name;
my @args = map {$_->value} @{$reqobj->args};
my $response = example_sum(@args);
my $resobj = RPC::XML::response->new($response);

   RPC::XML::Parserは渡されてきたXMLデータ(ここでは$requestに格納されていると仮定しています)を解析してメソッド名とパラメータを取り出してくれます。パラメータはRPC::XML::stringのなどのオブジェクトになっているので、valueメソッドを利用すればデータを取り出すことができます。structはハッシュとして、arrayは配列として取り出せるようになっているので、後はそれを処理して(ここではexample_sumを呼び出しています)、結果を返すだけです。結果をXMLデータに変換するには、RPC::XML::responseクラスを利用すれば簡単です。

1973年東京生まれ。エンジニア兼技術系ライター。株式会社はてな勤務。近著に「俺流Amazonの作り方」(アスキー)、「詳解RSS〜RSSを利用したサービスの理論と実践」(ディー・アート)など。趣味はラテン音楽と海外旅行と神輿。現在、家を荒らしまわるネズミの被害に頭を悩ませている。

連載バックナンバー

Think ITメルマガ会員登録受付中

Think ITでは、技術情報が詰まったメールマガジン「Think IT Weekly」の配信サービスを提供しています。メルマガ会員登録を済ませれば、メルマガだけでなく、さまざまな限定特典を入手できるようになります。

Think ITメルマガ会員のサービス内容を見る

他にもこの記事が読まれています