PR

Webカメラで撮影した写真をセピア調に演出するアプリを作る

2013年9月3日(火)
薬師寺 国安

カメラのデバイスを取得し、ピクチャライブラリ内のセピア画像を取得する処理

ComboBox内をクリアしておきます。

FindAllAsyncメソッドで全てのビデオキャプチャデバイスを列挙して、DeviceInfomationオブジェクトのコレクションである、myCameraコレクション変数に格納します。

Webカメラが実装されている場合は、コレクション変数myCameraが格納しているデバイスの個数分、繰り返し変数iで反復処理を行います。
DeviceInfomationの列挙体である、変数cameraInfoで、コレクション変数myCameraが格納しているデバイスを参照させます。cameraComboBoxにAddメソッドで取得したデバイス名を追加していきます。フロントカメラやリアカメラを実装しているタブレットPCでは、2つのデバイス名が追加されます。cameraComboBoxのSelectedIndexが0より小さい場合、つまりカメラのデバイスが選択されていない場合は、最初のデバイスを選択状態にします。選択されている場合は、選択されたデバイスが選択状態になります。
「Attach Camera」アイコンの使用を可能にします。

ピクチャライブラリ内のSepiaSourceImageサブフォルダ内の画像を取得して、GridViewに「削除」ボタンを付けて表示する、AddPhotoプロシージャを実行します。

ピクチャライブラリにアクセスし、GetFilesAsyncメソッドでファイルを取得して、コレクションメンバ変数myPictureFilesに格納します。
コレクション変数myPictureFiles内のファイルを変数myPhotoに格納しながら、以下の処理を繰り返します。

ファイル名に「sepia」という文字列の含まれているファイルがあった場合は、「Folder」アイコンの使用を可能にし、それ以外は不可とします。

エラーが発生した場合はErrorShowプロシージャを実行します。

非同期処理で行われるためメソッドの先頭にAsyncを追加します。

  Private Async Sub DataShow()
    AppBar1.Visibility = Xaml.Visibility.Visible
    Try
      cameraComboBox.Items.Clear()
      myCamera = Await DeviceInformation.FindAllAsync(DeviceClass.VideoCapture)
      For i As Integer = 0 To myCamera.Count - 1
        Dim cameraInfo = myCamera(i)
        cameraComboBox.Items.Add(cameraInfo.Name)
      Next
      If cameraNo < 0 Then
        cameraComboBox.SelectedIndex = 0
        shutterButton.IsEnabled = True
      Else
        cameraComboBox.SelectedIndex = cameraNo
        shutterButton.IsEnabled = True
      End If
      AddPhoto()
      Dim myFolder As StorageFolder = Windows.Storage.KnownFolders.PicturesLibrary
      myPictureFiles = Await myFolder.GetFilesAsync()
 
      For Each myPhoto In myPictureFiles
        If myPhoto.Path.Contains("sepia") Then
          ichiranButton.IsEnabled = True
        Else
          ichiranButton.IsEnabled = False
        End If
      Next
    Catch
      ErrorShow()
    End Try
  End Sub

Webカメラが装備されてなくてエラーが発生した時の処理

警告メッセージを表示し、「Attach Camera」の使用を不可として、処理を抜けます。非同期処理で行われるためメソッドの先頭にAsyncを追加します。

  Private Async Sub ErrorShow()
    Dim message As New MessageDialog("カメラが装備されておりません。")
    Await message.ShowAsync
    shutterButton.IsEnabled = False
    Exit Sub
  End Sub

GridViewに「削除」ボタンを付けて、画像を一覧表示する処理

ピクチャライブラリのSepiaSourceImageサブフォルダにアクセスします。
GetFilesAsyncメソッドでファイルを取得して、コレクションメンバ変数myPictureFilesに格納します。
SepiaSourceImageサブフォルダ内にファイルがなかった場合は、Image1には何も表示しません。

コレクションメンバ変数myPictureFiles内のファイルを、変数myPhotoFileに格納しながら、以下の処理を繰り返します。

新しいBitmapImageのインスタンスbmpを作成します。SetSourceメソッドに、

Await myPhotoFile.OpenSequentialReadAsync

と指定して、OpenSequentialReadAsyncメソッドで、順次読み取りアクセス用のストリームを開き、BitmapSourceのソースイメージに指定します。

新しいImageのインスタンスmyImageオブジェクトを指定します。WidthとHeightプロパティを指定し、Sourceプロパティにbmpオブジェクトを指定します。

TextBlockの新しいインスタンスmyFileNameオブジェクトを作成します。
SubStringメソッドでファイル名の先頭から20文字を取り出します。2013年01月01日10時10分10秒といった形式の文字列が取り出され、Textプロパティに指定します。文字サイズは10とし、中央揃えとしておきます。

新しいButtonのインスタンスmyButtonオブジェクトを作成します。
Contentプロパティに「削除」、文字サイズに18と指定し、Tagプロパティに1ずつ加算されるメンバ変数noの値を文字列に変換して指定します。この値は、どの「削除」ボタンがクリックされたかを判別するために使用します。文字は中央揃えとしておきます。

新しいStackPanelのインスタンスmyStackPanelオブジェクトを作成します。Marginに3を指定して余白を設けます。myStackPanelオブジェクトにAddメソッドで、myImage、myFileName、myButtonを追加します。最後に、GridViewにAddメソッドでmyStackPanelオブジェクトを追加します。これで、サイズが160×120で、その下にファイル名と「削除」ボタンの付いた画像の一覧がGridViewに表示されます。
AddHandlerメソッドで、myButtonがクリックされた時のイベントハンドラを追加します。イベントハンドラ内では以下の処理を行います。

ButtonのTagプロパティの値を取得して変数myNoに格納します。この値を数値にキャストして、変数myIndexに格納します。コレクションメンバ変数myPictureFiles内のmyIndexに位置するファイルを、DeleteSAsyncメソッドで削除します。

「削除しました。」のメッセージを表示し、GridViewをクリアし、メンバ変数noを0で初期化して、再描画するために、AddPhotoプロシージャを実行します。

コレクションメンバ変数内のファイルの個数をCountプロパティで取得し、変数Indexに格納します。Indexが0の時、つまりファイルが存在していない場合は、処理を抜けます。
ファイルが存在している場合は、GridViewのSelectedIndexに変数Index-1の値を指定します。-1しているのはSelectedIndexの値は0から始まるためです。

ScrollIntoViewメソッドで、指定された項目が表示されるように、リストをスクロールします。
常に新しい写真が選択された状態になります。「Sepia調に変換」ボタンの使用を可能にします。
非同期処理で行われるためメソッドの先頭にAsyncを追加します。

  Private Async Sub AddPhoto()
    no = 0
    Try
      Dim myFolder As StorageFolder = Windows.Storage.KnownFolders.PicturesLibrary
      Dim mySubFolder = Await myFolder.CreateFolderAsync("SepiaSourceImage", CreationCollisionOption.OpenIfExists)
      myPictureFiles = Await mySubFolder.GetFilesAsync()
 
      If myPictureFiles.Count = 0 Then Image1.Source = Nothing
      For Each myPhotoFile In myPictureFiles
        Dim bmp As New BitmapImage
        bmp.SetSource(Await myPhotoFile.OpenSequentialReadAsync)
        Dim myImage As Image = New Image
        myImage.Width = 160
        myImage.Height = 120
        myImage.Source = bmp
 
        Dim myFileName As New TextBlock
        myFileName.Text = myPhotoFile.Name.Substring(0, 20)
        myFileName.FontSize = 10
        myFileName.HorizontalAlignment = Windows.UI.Xaml.HorizontalAlignment.Center
 
        Dim myButton As New Button
        With myButton
          .Content = "削除"
          .FontSize = 18
          .Tag = no.ToString
          .HorizontalAlignment = Xaml.HorizontalAlignment.Center
        End With
        Dim myStackPanel As StackPanel = New StackPanel
        myStackPanel.Margin = New Thickness(3)
        myStackPanel.Children.Add(myImage)
        myStackPanel.Children.Add(myFileName)
        myStackPanel.Children.Add(myButton)
        GridView1.Items.Add(myStackPanel)
 
        AddHandler myButton.Click, Async Sub(delSender As Object, delArgs As RoutedEventArgs)
          Dim myNo As String = DirectCast(delSender, Button).Tag
          Dim myIndex As Integer = CInt(myNo)
          Await myPictureFiles(myIndex).DeleteAsync
          Dim myMessage As New MessageDialog("削除しました。")
          Await myMessage.ShowAsync
          GridView1.Items.Clear()
          no = 0
          AddPhoto()
            End Sub
        no += 1
      Next
      myPictureFiles = Await mySubFolder.GetFilesAsync()
      Index = myPictureFiles.Count
      If Index = 0 Then
        Exit Sub
      Else
        GridView1.SelectedIndex = Index - 1
        GridView1.ScrollIntoView(GridView1.SelectedItem)
      End If
      changeSepiaButton.IsEnabled = True
    Catch
      Exit Sub
    End Try
  End Sub
Think IT会員限定特典
  • セピア調の写真を作るアプリ

薬師寺国安事務所

薬師寺国安事務所代表。Visual Basic プログラミングと、マイクロソフト系の技術をテーマとした、書籍や記事の執筆を行う。
1950年生まれ。事務系のサラリーマンだった40歳から趣味でプログラミングを始め、1996年より独学でActiveXに取り組む。1997年に薬師寺聖とコラボレーション・ユニット PROJECT KySS を結成。2003年よりフリーになり、PROJECT KySS の活動に本格的に参加、.NETやRIAに関する書籍や記事を多数執筆する傍ら、受託案件のプログラミングも手掛ける。Windows Phoneアプリ開発を経て、現在はWindows ストア アプリを多数公開中

Microsoft MVP for Development Platforms - Client App Dev (Oct 2003-Sep 2012)。Microsoft MVP for Development Platforms - Windows Phone Development(Oct 2012-Sep 2013)。Microsoft MVP for Development Platforms - Client Development(Oct 2013-Sep 2014)。Microsoft MVP for Development Platforms-Windows Platform Development (Oct 2014-Sep 2015)。

連載バックナンバー

Think IT会員サービス無料登録受付中

Think ITでは、より付加価値の高いコンテンツを会員サービスとして提供しています。会員登録を済ませてThink ITのWebサイトにログインすることでさまざまな限定特典を入手できるようになります。

Think IT会員サービスの概要とメリットをチェック

他にもこの記事が読まれています