ロジックコードを記述する

次に、ソリューションエクスプローラー内のMainWindow.xamlを展開して表示される、MainWindow.xaml.vbをダブルクリックしてリスト4のコードを記述します。

ロジックコードを記述する

リスト4 (MainWinsdow.xaml.vb)

Option Strict On
Imports Microsoft.Kinect
Class MainWindow

ウィンドウが読み込まれた時の処理

Sliderの値を0で初期化し、TextBlock内に表示しておきます。

KinectSensorChooser1.KinectSensorChangedイベントで、Kinectが接続されているどうかを確認します。古いセンサーが動作している時は停止させ、新しいセンサーを取得します。ColorStream.EnableメソッドでKinect センサーのRGBカメラの動作を開始し、Kinectセンサーの動作を開始します。

SliderのMaximumプロパティに、最大高度角用 Kinect センサーを取得する、MaxElevationAngleプロパティを指定します。Minimumプロパティには、最小の仰角用 Kinect センサーを取得する、MinElevationAngleを指定します。チルトモーターの仰角範囲は±28°ですが、角度が0から開始しますので、最大高度角は27°、最小の仰角用は-27°と表示されます。例外が発生した場合はエラーを表示して処理を抜けます。

  Private Sub MainWindow_Loaded(sender As Object, e As System.Windows.RoutedEventArgs) Handles Me.Loaded
    Slider1.Value = 0
    TextBlock1.Text = CStr(Slider1.Value)
    AddHandler KinectSensorChooser1.KinectSensorChanged, Sub(kinectSender As Object, kinectArgs As DependencyPropertyChangedEventArgs)
      Dim oldSensor As KinectSensor = DirectCast(kinectArgs.OldValue, KinectSensor)
                       If oldSensor Is Nothing = False Then
                         StopKinect(oldSensor)
                       End If
 
        Dim newSensor As KinectSensor = DirectCast(kinectArgs.NewValue, KinectSensor)
                       If newSensor Is Nothing = True Then
                         Return
                       End If
 
                       newSensor.ColorStream.Enable()
                       Try
                         newSensor.Start()
                         Slider1.Maximum = newSensor.MaxElevationAngle
                         Slider1.Minimum = newSensor.MinElevationAngle
                       Catch ex As Exception
                         MessageBox.Show(ex.Message)
                         Exit Sub
                       End Try
                             End Sub
  End Sub

Kinectセンサーを停止するプロシージャ

Kinectセンサーが動作している場合はKinectセンサーを停止し、リソースを解放します。

  Private Sub StopKinect(sensor As KinectSensor)
    If sensor Is Nothing = False Then
      If sensor.IsRunning = True Then
        sensor.Stop()
        sensor.Dispose()
      End If
    End If
  End Sub

［実行］ボタンがクリックされた時の処理

Kinect センサーの仰角を取得するKinect.ElevationAngleプロパティに、整数型にキャストしたSlider1の値を指定します。

  Private Sub Button1_Click(sender As System.Object, e As System.Windows.RoutedEventArgs) Handles Button1.Click
    KinectSensorChooser1.Kinect.ElevationAngle = CInt(Slider1.Value)
  End Sub

ウィンドウが閉じられる時に発生するイベント

動作しているKinectセンサーである、KinectSensorChooser1.Kinectを引数にStopKinectプロシージャを実行します。

  Private Sub MainWindow_Closing(sender As Object, e As System.ComponentModel.CancelEventArgs) Handles Me.Closing
    StopKinect(KinectSensorChooser1.Kinect)
  End Sub

スライダーの値が変化した時に発生するイベント

TextBlockに整数型のSliderの値を、文字列にキャストして表示します。

    Private Sub Slider1_ValueChanged(sender As Object, e As System.Windows.RoutedPropertyChangedEventArgs(Of Double)) Handles Slider1.ValueChanged
    TextBlock1.Text = CStr(CInt(Slider1.Value))
  End Sub
End Class

以上で今回のサンプルは終了です。いかがでしたか。Kinectはセンサーだけでなくモーターも内蔵していますので、サンプルが動作してKinectが首を振る様子はちょっと感動的かと思います。

それでは、次回もお楽しみに。